5 REM--AHOY--FEB ISSUE--RELATIVE FILES--PROG PAGE 27
10 PRINT"[147]PHONE BOOK -- RELATIVE FILE DEMO":OPEN15,8,15,"I0"
20 PRINT"SETUP NEW FILE (Y/N)?";
30 GETA$:IFA$<>"N"ANDA$<>"Y"THEN30
40 IFA$="N"THENPRINT"NO":GOTO60
50 PRINT"YES":OPEN3,8,3,"@0:PHONEFILE,L,"+CHR$(40):GOTO100
60 OPEN7,8,7,"COUNTER,S,R":INPUT#7,N:CLOSE7:OPEN3,8,3,"PHONEFILE"
100 PRINT"[147]CHOOSE ONE:":PRINT"1- ENTER NAME, NUMBER":PRINT"2- SEARCH FOR NAME"
110 PRINT"3- DISPLAY ALL ENTRIES":PRINT"4- EXIT"
120 PRINT"ENTER CHOICE-->";
130 GETA$:A=VAL(A$):IFA<1ORA>4THEN130
140 ONAGOTO200,400,600,800
200 PRINT"[147]ACTIVE ENTRIES ="N
205 IFN=255THENPRINT"NO MORE ROOM IN FILE.":GOSUB990:GOTO100
210 PRINT"ENTER NAME, NUMBER:":I$="":J$=I$:INPUTI$,J$:IFI$=""ORJ$=""THEN100
220 IFLEN(I$)+LEN(J$)>37THENPRINT"ENTRY IS TOO LONG...":GOTO210
230 N=N+1:PRINT#15,"P"CHR$(3)CHR$(N)CHR$(0):PRINT#3,I$","J$:GOTO100
400 IFN=0THENPRINT"NO ENTRIES IN FILE.":GOSUB990:GOTO100
405 PRINT"[147]ENTER NAME TO SEARCH FOR:":N$="":INPUTN$:IFN$=""THEN100
410 J=0:FORX=1TON:PRINT#15,"P"CHR$(3)CHR$(X)CHR$(0):INPUT#3,I$,J$
415 IFI$<>N$THEN430
420 X=N:J=N
430 NEXT:IFJ=0THENPRINT"NOT FOUND.":GOSUB990:GOTO100
440 PRINTN$,J$:GOSUB990:GOTO100
600 PRINT"[147]HIT F1 TO PAUSE AND CONTINUE"
610 IFN=0THENPRINT"NO ENTRIES IN FILE.":GOSUB990:GOTO100
620 FORX=1TON:PRINT#15,"P"CHR$(3)CHR$(X)CHR$(0):INPUT#3,I$,J$:PRINTI$,J$
625 GETA$:IFA$<>"[133]"THEN630
627 GETA$:IFA$<>"[133]"THEN627
630 NEXT:GOSUB990:GOTO100
800 PRINT"[147]EXIT, ARE YOU SURE (Y/N)? ";
810 GETA$:IFA$<>"N"ANDA$<>"Y"THEN810
820 IFA$="N"THENPRINT"NO":GOTO100
830 PRINT"YES":OPEN7,8,7,"@0:COUNTER,S,W":PRINT#7,N:CLOSE7:INPUT#15,A,B$,C,D
840 CLOSE15:END
990 PRINT"HIT RETURN TO CONTINUE."
995 GETA$:IFA$<>CHR$(13)THEN995
999 RETURN